1

INTRODUCERE ÎN ANALIZA ASISTATĂ DE

CALCULATOR A CIRCUITELOR ELECTRONICE
DE COMUTAŢIE. MODELE SPICE

1. OBIECTUL APLICAŢIEI

Aplicaţia are ca scop familiarizarea cu metodele de analiză şi de modelare

SPICE a circuitelor electronice care lucrează în comutaţie. Pentru început sunt
prezentate succint noţiunile minimale necesare pentru a putea înţelege fişierul de
circuit al exemplelor prezentate în desfăşurarea aplicaţiei şi pentru a putea efectua
analiza SPICE de regim tranzitoriu. Acest tip de analiză este folosit pentru analiza
circuitelor în comutaţie. Ulterior în aplicaţie sunt prezentate exemple care au scopul
de a evidenţia procesele de comutaţie precum şi problemele specifice puse de
circuitele în comutaţie în realizarea modelului şi simulării SPICE.

2. INTRODUCERE ÎN SPICE

SPICE = "Simulation Program with Integrated Circuit Emphasis". PSpice este

o versiune a programului SPICE, versiune dezvoltată de MicroSim Corporation.

2.1. Etapele simulării

- Se denumesc nodurile şi componentele circuitului care trebuie analizat.
- Se creează fişierul corespunzător de circuit (<nume>.CIR) folosind editorul
PSpice.
- Se execută simularea SPICE folosind fişierul de circuit creat anterior.
- Se vizualizează rezultatele simulării, care se află în fişierul de circuit
<nume>.OUT, folosind editorul PSpice, sau orice alt editor de text.
- Se vizualizează formele de undă rezultate în urma simulării folosind fişierul
de date <nume>.DAT şi programul [Link], componentă a pachetului de
programe PSpice.

2.2. Fişierul de circuit

Structura fişierului de circuit, care poate fi observată şi în exemplele
prezentate în desfăşurarea aplicaţiei, este următoarea:
- Linie de titlu.
10 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE

- Comentarii. Sunt opţionale, însă foarte utile pentru îmbunătăţirea clarităţii

fişierului de circuit.
- Instrucţiuni pentru adresarea unor biblioteci.
- Descrierea componentelor circuitului: nume în cadrul circuitului, nodurile
între care este conectată, valoarea - dacă este componentă pasivă, sau tipul
componentei - dacă este componentă activă.
Ex. R15 2 3 1k
D7 5 6 D1N4148
- Instrucţiuni care descriu tipul analizei ce trebuie efectuată.
- Instrucţiuni care descriu ce date şi sub ce formă să fie salvate în urma
simulării în fişierele de ieşire.
- Instrucţiunea .END .

2.3. Convenţii folosite în fişierul de circuit

Pentru editarea fişierului de circuit este necesar ca fiecare nod din circuit să
primească un nume. Numele unui nod poate avea maxim 128 de caractere
alfanumerice. Este obligatoriu ca un nod din circuit să fie masa, care primeşte prin
convenţie numele "0". Celelalte noduri pot fi denumite arbitrar şi nu este necesar să
fie în secvenţa 1, 2, 3 etc.
Instrucţiunile sunt precedate de caracterul " . " (Ex.: .PROBE).
Linia de titlu trebuie să fie prima, iar ultima linie trebuie să fie instrucţiunea
.END, care indică locul unde se termină fişierul de circuit. Toate celelalte linii ale
fişierului de circuit se află între linia de titlu şi cea de sfârşit, putând fi introduse în
orice ordine.
Programul PSpice este "case insensitive", adică nu are importanţă dacă se
folosesc litere mari sau mici.
Utilizatorul poate indica puterile lui 10 folosind următoarele sufixuri: f pentru
1e-15, p pentru 1e-12, n pentru 1e-9, u pentru 1e-6, m pentru 1e-3, k pentru 1e3,
meg pentru 1e6, g pentru 1e9, t pentru 1e12. Următoarele caractere după sufix
sunt ignorate.
Ex. 10mv = 10 ⋅ 10−3 V. Litera " V " este ignorată.
1uFarad = 10−6 µF . Litera " F " este ignorată.

2.4. Liniile fişierului de circuit

2.4.1. Linia de titlu

Este prima linie a fişierului de circuit. Descrie conţinutul fişierului de circuit
sau poate fi doar o linie liberă. Nu este luată în considerare la efectuarea analizei.

2.4.2. Comentarii
Introducere [n Spice 11
Măresc claritatea fişierului de circuit şi pot fi:
- Linii de comentariu. Au caracterul "*" în prima coloană urmat de orice text.
Ex. *Modulul de comandă
- Comentarii în cadrul unei linii de program. Pentru a comenta o linie de
program se pune caracterul ";" urmat de orice text.
Ex. R11 1 2 1k ; Polarizare

2.4.3. Instrucţiuni pentru adresarea unei biblioteci

Dacă modelul unei componente din circuit se găseşte într-o bibliotecă de
modele, atunci trebuie indicat numele bibliotecii respective precum şi calea pe hard-
disk.
Ex. .LIB C:\PSPICE\LIB\[Link]

2.4.4. Descrierea componentelor circuitului

De reţinut că, întotdeauna, curentul printr-o componentă de circuit curge prin
componenta respectivă de la nodul + (primul) la nodul - (al doilea).

a) Parametri
Pentru a simplifica modificarea valorilor componentelor din circuit se pot defini
parametri. Valoarea unui parametru este luată în considerare oriunde în circuit
apare acel parametru.
Ex. .PARAM RLOAD = 5
R10 15 0 {RLOAD}
R15 20 30 {3*RLOAD}

b) Componente pasive
Rezistenţă R<nume> <nod+> <nod-> <valoare>
Inductanţă L<nume> <nod+> <nod-> <valoare> <IC=<valoarea iniţială a
curentului prin inductanţă>>
Condensator C<nume> <nod+> <nod-> <valoare> <IC=<valoarea iniţială
a tensiunii pe condensator>>
Coeficient de K<nume> L<nume1> L<nume2> <valoarea coeficientului
de cuplaj mutual cuplaj>

c) Surse independente de tensiune şi curent folosite pentru analiza de

regim tranzitoriu
Sursă independentă de tensiune
V<nume> <nod+> <nod-> [<valoare de c.c.>] [<specificaţii de regim tranzitoriu>]
Sursă independentă de curent
I<nume> <nod+> <nod-> [<valoare de c.c.>] [<specificaţii de regim tranzitoriu>]
12 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE

Specificaţii de regim tranzitoriu

PULSE(<tensiune iniţială> <tensiune finală> <întârziere faţă de origine> <timp de
creştere> <timp de cădere> <durata palierului pe tensiune finală> <perioada>)
Descrie o sursă de tensiune care generează un semnal periodic de tip
impuls, cu parametrii specificaţi în corpul instrucţiunii. Bineînţeles, dacă se dau
valori parametrilor în mod corespunzător, se poate obţine semnal trapezoidal,
triunghiular şi chiar neperiodic, dacă <perioada> indicată este mai mare decât
intervalul pe care se face analiza.
SIN(<valoare medie> <amplitudine> <frecvenţă> <întârziere faţă de origine>
<factor de amortizare> <faza în grade>)
Descrie o sursă de tensiune sinusoidală, cu parametrii indicaţi în corpul
instrucţiunii. Pentru aplicaţiile prezentate în această carte sintaxa este:
SIN(0 <amplitudine> <frecvenţă> 0 0 <faza în grade>)

d) Surse de tensiune/curent controlate în tensiune/curent

Sursă de tensiune controlată în tensiune
E<nume> <nod+> <nod-> <nod control +> <nod control -> <câştig>
Sursă de curent controlată în curent
F<nume> <nod+> <nod-> <numele sursei independente de tensiune folosită ca
senzor de curent> <câştig>
Sursă de tensiune controlată în curent
H<nume> <nod+> <nod-> <numele sursei independente de tensiune folosită ca
senzor de curent> <transrezistenţă>
Sursă de curent controlată în tensiune
G<nume> <nod+> <nod-> <nod control +> <nod control -> <transconductanţă>

e) Folosirea modelelor predefinite în PSpice

În PSpice există modele predefinite pentru descrierea unor componente
active, contactoare controlate în tensiune/curent etc.
Pentru folosirea acestor modele sunt necesare două instrucţiuni.
Dioda
O instrucţiune asociază unui <nume model> un <tip model> generic cu
anumite valori ale parametrilor acelui <tip model>.
Ex. .MODEL <nume model> <tip model>(<parametri>)
.MODEL POWER_DIODE D(RS=1m CJO=500p)
O altă instrucţiune descrie o anumită componentă din circuit ca având
modelul <nume model>.
Ex. D<nume> <nod+> <nod-> <nume model>
D15 1 2 POWER_DIODE
Introducere [n Spice 13
Toţi <parametrii> din paranteze sunt opţionali. Dacă nu este indicat nici un
parametru, atunci vor fi folosite valorile implicite ale parametrilor.
Comutatorul controlat în tensiune
Acest tip de comutator este reprezentat printr-o rezistenţă de valoare foarte
mică RON, atunci când tensiunea la bornele de comandă este mai mare decât
VON, şi printr-o rezistenţă de valoare foarte mare ROFF, atunci când tensiunea la
bornele de comandă este mai mică decât VOFF. Comutatorul este bidirecţional.
Ex. .MODEL <nume model> VSWITCH(<parametri>)
.MODEL RELEU VSWITCH(RON=1m VON=5 ROFF=1MEG VOFF=1)
S<nume> <nod+> <nod-> <nod control +> <nod control -> <nume model>
S5 2 7 9 0 RELEU

f) Subcircuite
Folosirea unui subcircuit implică două etape: definirea subcircuitului şi
apelarea subcircuitului.
Definirea subcircuitului
Poate fi făcută fie în fişierul principal de circuit, fie într-un alt fişier, care va fi
apelat cu instrucţiunea .LIB sau .INC. Definirea fişierului de circuit se face cu
instrucţiunea:
.SUBCKT <nume> <nod1> <nod2>. . .<nodn> PARAMS:
<param1>=<valoare>. . . descrierea subcircuitului
.ENDS
Nodurile subcircuitului pot primi orice nume. Numele nodurilor din subcircuit
sunt independente de numele nodurilor din circuitul principal. Aceasta înseamnă că
două noduri, unul din circuitul principal şi unul din subcircuit, care au acelaşi nume,
nu vor fi automat interconectate. Excepţie face nodul " 0 ", care este nod comun, de
masă.
Apelarea subcircuitului
Apelarea subcircuitului se face cu instrucţiunea:
X<nume> <nod1> <nod2>. . .<nodn> <nume> PARAMS:
<param1>=<valoare>. . .
Parametrii care primesc valori prin specificaţia "PARAMS" vor fi automat
actualizaţi cu noile valori în cadrul subcircuitului, permiţând astfel particularizarea
unui model generic de subcircuit cu anumite valori.

g) Descrierea surselor comandate în tensiune prin funcţii de transfer

Sursele comandate în tensiune (E, G) acceptă descrierea prin funcţii de
transfer (Analog Behavioral Modeling). Aceasta înseamnă că tensiunea/curentul
generate de aceste tipuri de surse pot fi descrise printr-o funcţie definită de
utilizator.
14 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE

VALUE: E<nume> <nod+> <nod-> VALUE = {expresie}

Valoarea tensiunii de ieşire este rezultatul evaluării funcţiei din {expresie}

TABLE: E<nume> <nod+> <nod-> TABLE{expresie} = <descrierea prin puncte a

funcţiei de transfer>
Funcţia de transfer este descrisă prin perechi de puncte (x, y), unde x este
valoarea mărimii de intrare descrisă prin {expresie}, iar y este valoarea mărimii de
ieşire. Între două perechi de puncte valoarea mărimii de ieşire este calculată prin
interpolare liniară.
LAPLACE: E<nume> <nod+> <nod-> LAPLACE {expresie} = {transformata
Laplace a funcţiei de transfer, mărimea de intrare fiind dată de {expresie} }

2.4.5. Instrucţiuni care descriu tipul analizei ce trebuie efectuată

Analiza de regim tranzitoriu
.TRAN <print step> <timp final> <timp start salvare> <pas maxim>
[SKIPBP]
Analiza este făcută pe intervalul (0, <timp final>). Datele în fişierele de ieşire
*.OUT şi *.DAT sunt salvate pentru intervalul (<timp start salvare>, <timp final>).
Datele în fişierul de ieşire *.OUT sunt salvate cu un pas de timp dat de <print step>.
La analiza de regim tranzitoriu, pasul de timp al simulatorului se modifică automat în
funcţie de viteza de variaţie a mărimilor calculate, în scopul asigurării unui anumit
nivel de precizie. Astfel, pe anumite intervale, pasul de timp poate creşte foarte
mult. Se pot pierde astfel date semnificative din formele de undă, dat fiind că la
vizualizarea formelor de undă se face interpolare între două puncte adiacente.
Pasul de timp poate fi limitat prin <pas maxim>. Dacă în corpul instrucţiunii este
prezentă specificaţia " SKIPBP " – (skip bias point), vor fi folosite condiţiile iniţiale
indicate în circuit prin specificaţia "IC".
Analiza Fourier
.FOUR <frecvenţa fundamentalei> <mărimi de ieşire>
Se efectuează analiza Fourier pentru <mărimi de ieşire>, obţinându-se
valorile pentru primele nouă componente spectrale (amplitudine şi fază în valori
absolute şi normate la valorile obţinute pentru fundamentală). Rezultatele sunt
salvate în fişierul *.OUT.

2.4.6. Instrucţiuni care descriu modul de salvare a datelor în fişierele de

ieşire
.PRINT TRAN <mărimi de ieşire>
Introducere [n Spice 15
Această instrucţiune specifică faptul că valorile pentru <mărimi de ieşire>
rezultate în urma analizei TRAN vor fi salvate în fişierul *.OUT la intervale dictate de
<print step>. Se obţin doar valorile respective, nu şi o reprezentare grafică.
.PROBE <mărimi de ieşire>
Instrucţiunea aceasta specifică faptul că toate valorile pentru <mărimi de
ieşire> vor fi salvate în fişierul *.DAT, fiind folosite ulterior pentru reprezentarea
grafică a rezultatelor simulării. Dacă nu se specifică <mărimi de ieşire>, vor fi
salvate datele pentru toate mărimile electrice din circuit. Pentru vizualizarea şi
analiza rezultatelor simulării este comod să avem datele pentru toate mărimile din
circuit, însă, în anumite situaţii, fişierul *.DAT poate avea dimensiuni foarte mari.

2.4.7. Instrucţiunea .END

.END
Această instrucţiune trebuie să încheie descrierea fişierului de circuit.

2.5. Executarea simulării PSpice

Din meniul principal se selectează Analysis, Run PSPICE.

2.6. Vizualizarea rezultatelor din fişierul *.OUT

Rezultatele simulării din fişierul *.OUT pot fi vizualizate selectând din meniul
principal Files, Browse Output sau orice alt editor de text.

2.7. Vizualizarea rezultatelor din fişierul *.DAT

Rezultatele simulării din fişierul *.DAT pot fi vizualizate grafic selectând din
meniul principal Probe, Run Probe.

2.8. Surse de erori

Noduri flotante. Este necesar ca fiecare nod să aibă o cale de c.c. către
masă. De asemenea este necesar ca la fiecare nod să fie cel puţin două conexiuni.
În caz contrar simulatorul nu poate calcula punctul static de funcţionare şi va furniza
mesaj de eroare. Problema se remediază prin conectarea unei rezistenţe de
valoare foarte mare (1G, de exemplu) către masă.
Bucle de inductanţe sau de surse de tensiune. PSpice nu acceptă
existenţa buclelor de rezistenţă zero, bucle care pot fi formate din surse ideale de
tensiune şi/sau inductanţe. Problema poate fi rezolvată prin ruperea buclei şi
înserierea unei rezistenţe de valoare foarte mică.
Probleme de convergenţă. Aceste probleme pot să apară în special la
analiza de regim tranzitoriu şi în special în cazul circuitelor care lucrează în
comutaţie. Din punct de vedere al convergenţei putem spune că analiza de regim
tranzitoriu a circuitelor de comutaţie este cea mai dificilă, cere cel mai mare efort
16 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE

de calcul (şi implicit cel mai mult timp) şi pune cele mai mari probleme în modelarea
circuitelor respective. Pentru evitarea problemelor de convergenţă trebuie evitate
variaţiile foarte rapide ale mărimilor din circuit, variaţii care ar putea determina
scăderea pasului de timp al simulatorului sub valoarea minimă acceptată. Pot fi de
asemenea mărite valorile parametrilor VNTOL (toleranţa absolută a tensiunilor) şi
ABSTOL (toleranţa absolută a curenţilor).
La analiza de regim tranzitoriu, parametrul ITL5, care determină numărul
maxim de iteraţii, trebuie să primească valoarea zero (număr nelimitat de iteraţii).
Numărul maxim implicit de 5000 de iteraţii poate fi foarte rapid atins la analiza de
regim tranzitoriu.
Toate aceste modificări ale parametrilor se pot face din meniul Analysis,
Options.

3. DESFĂŞURAREA APLICAŢIEI

În această aplicaţie vor fi analizate dioda semiconductoare de putere, tiristorul

şi tranzistorul TEC-MOS de putere, din punct de vedere al caracteristicilor
importante pentru regimul de comutaţie.
Deoarece în PSpice notarea surselor de tensiune se face folosind litera "V",
toate referirile la surse de tensiune incluse în fişierul de circuit sau forme de undă
ale tensiunilor rezultate în urma simulării sunt făcute folosind această literă.
Referirile la valori ale tensiunilor care nu au legătură directă cu PSpice sunt făcute
respectând notaţia cu litera "U".
3.1. Comutaţia diodei pe sarcină rezistivă
Considerăm circuitul de test din figura 1.

Fig. 1 Circuitul de test pentru studiul comutaţiei diodei

pe sarcină rezistivă.

În continuare este prezentat fişierul de circuit corespunzător:

* Circuit pentru analiza caracteristicilor de comutatie
* ale diodei pe sarcina rezistiva
.LIB C:\PSPICE\LIB\[Link] ; apelarea bibliotecii de diode
.PARAM VSUP=10 ; definirea parametrului VSUP
* Sursa de test
V1 1 0 PULSE({VSUP} -100 10n 1p 1p 100n 200n)
R1 1 2 2
Desfăşurarea aplicaţiei 17
* Dioda D1 de tip D1N3889, al carei model se gaseşte in biblioteca [Link]
D1 2 0 D1N3889
* Specificatii pentru analiza de regim tranzitoriu
.TRAN 10.000n 150.000n 0 100.000p
* Numar nelimitat de iteraţii
.OPTIONS ITL5 = 0
* Specificaţii pentru analiza de tip parametric. Parametrul VSUP primeşte pe rând
valorile
* din lista. Pentru fiecare valoare este efectuată analiza de regim tranzitoriu.
.STEP PARAM VSUP LIST 1 5 10 15 20
.END
Sursa de tensiune V1 generează semnal periodic, cu palierul superior având
valoarea dată de parametrul VSUP , iar palierul inferior de -100V. Valoarea implicită a
parametrului este VSUP =10V, permiţând obţinerea unui curent direct prin diodă de
aproximativ 5A. Tensiunea de -100V polarizează invers dioda, permiţând studiul
comutaţiei din conducţie în blocare. Timpul de cădere/creştere al tensiunii generate
de V1 este foarte mic, pentru a influenţa cât mai puţin procesul de comutaţie.
Formele de undă ale tensiunii pe diodă şi ale curentului prin diodă la comutarea în
blocare sunt prezentate în figura 2.
Curentul direct prin diodă este dat de relaţia:
VSUP −U F
I FM = (1)
R1
unde U F este căderea de tensiune pe dioda D1 aflată în conducţie.
În intervalul (0,ts) are loc evacuarea sarcinii stocate în joncţiune. Curentul
invers este constant:
U R Qs
I RM = = (2)
R1 ts
unde U R este tensiunea de polarizare inversă a diodei D1 .
În intervalul (ts,trr) se produce încărcarea capacităţii Cr a joncţiunii, timp în
care tensiunea pe joncţiune creşte până la valoarea tensiunii sursei de polarizare
inversă, iar curentul tinde către valoarea staţionară I R .
18 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE

Fig. 2 Comutarea diodei în blocare pe sarcină rezistivă.

Sarcina electrică totală este: (3)

t rr

Qrr = Qs + ∫ iR dt
ts

Simularea SPICE
a) Se încarcă fişierul L1_1.CIR. Se intră în editorul de circuit şi se
comentează linia .STEP (* în prima coloană).
b) Se execută simularea: Analysis, Run PSpice.
c) În continuare, folosind programul [Link], se vizualizează formele de
undă pentru tensiunea pe diodă, v(2) şi curentul prin diodă, i(D1). Procedura pentru
vizualizarea acestor forme de undă va fi descrisă în detaliu, pentru a permite
familiarizarea cu lucrul cu meniurile din Probe.
Se introduce încă un grafic: din meniul Plot Control se selectează Add plot,
Exit.
Se selectează Add Trace, apoi se tastează v(2), Enter.
Se selectează al doilea grafic: Plot Control, Select Plot, săgeata ↓, Exit. Se
selectează Add Trace, apoi se tastează i(D1), Enter.
În acest moment sunt disponibile pe ecran cele două forme de undă. Pentru
a putea analiza procesul de comutaţie, este necesar să mărim zona de interes.
Presupunem că dorim să vizualizăm procesul de comutare în blocare. Se
Desfăşurarea aplicaţiei 19
selectează Zoom, Specify region. Cursorul disponibil pe ecran va fi folosit pentru
marcarea colţurilor opuse ale ariei de interes. Folosind săgeţile se plasează
cursorul pe unul din colţuri. Se apasă tasta Space. Se plasează cursorul pe colţul
diagonal. Se apasă tasta Space. Dacă zona selectată trebuie mărită încă o dată, se
repetă paşii anteriori. Dacă zona selectată permite vizualizarea procesului de
comutaţie, se apasă tasta Esc. Oricând se poate reveni la imaginea iniţială
selectând Zoom, Auto Range.
Folosind Cursor, se determină I F ,I R ,t s ,trr . Se estimează Qs ,Qrr folosind relaţiile
(2) şi (3).
d) Se selectează zona corespunzătoare procesului de comutaţie în conducţie.
Se vizualizează formele de undă v(2) şi i(D1) în această situaţie.
e) Se selectează Zoom, Auto Range. Se vizualizează puterea disipată
instantanee pe diodă. În ce momente este această putere maximă? Să se
vizualizeze folosind Zoom zonele corespunzătoare. Să se determine puterea
disipată de diodă în comutaţie la frecvenţa f=1kHz.
f) De ce a fost definit palierul superior al tensiunii generate de V1 ca
parametru?
g) De ce în specificaţiile de regim tranzitoriu a fost indicat <pas maxim> de
timp de 100ps? Din meniul Analysis, Transient, <step ceiling> se şterge valoarea
100p. Pasul de timp nu este în acest fel limitat. Se reia simularea de la punctul b).
Se vizualizează formele de undă v(2), i(D1). Ce deosebiri se constată?
h) Se revine în meniul principal PSpice. În meniul Analysis, Transient, <step
ceiling> se tastează valoarea 100p. Se selectează Files, Edit şi se scoate
comentariul din linia *.STEP. Se revine în meniul principal. Astfel analiza de tip
parametric este validată iar parametrul VSUP va primi pe rând valorile 1, 5, 10, 15,
20V, permiţând obţinerea unui curent direct prin diodă de aproximativ 0,5, 2,5, 5,
7,5, 10A, respectiv. Simulatorul va executa analiza de regim tranzitoriu pentru
fiecare valoare a parametrului VSUP .
Se repetă punctele b), c). d). La punctul c) se vor determina mărimile cerute
pentru fiecare valoare a parametrului VSUP .
Se trasează graficul trr ( I F ) .

3.2. Comutarea în blocare a tiristorului pe sarcină R-L

Modelul simplificat al tiristorului

Tiristorul nu are în PSpice un model predefinit, aşa cum au celelalte
componente active: dioda, tranzistorul bipolar, tranzistorul MOS etc. Este necesar
deci să fie definit un model al tiristorului folosind un subcircuit. În biblioteca
[Link] este definit un model care ţine seama de multe dintre caracteristicile
de comutaţie ale tiristorului. Modelul respectiv caracterizează foarte bine tiristorul
20 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE

însă, având multe componente, micşorează foarte mult viteza de simulare. De

aceea, în majoritatea aplicaţiilor simple, este foarte util modelul simplificat prezentat
în figura 3a. Modelul respectiv ţine cont de următoarele caracteristici principale ale
tiristorului: comanda prin aplicarea unui semnal de amorsare pe poartă, existenţa
unui timp t ON de intrare în conducţie, pierderea controlului porţii după ce tiristorul a
intrat în conducţie, blocarea tiristorului atunci când curentul prin el scade sub
valoarea de menţinere.
În continuare este prezentat fişierul de circuit corespunzător - [Link].
Fişierul respectiv poate fi inclus într-o bibliotecă şi apelat cu numele SCR1. Se
poate remarca faptul că în modelul tiristorului a fost inclusă şi sursa de tensiune de
comandă, care generează semnal de tip PULSE, cu parametri ce pot fi setaţi cu
valorile dorite la apelarea modelului. Parametrii sunt: TDLY - decalajul impusului de
comandă faţă de trecerea prin zero, WIDTH- lăţimea impulsului de comandă, T -
perioada impulsului de comandă, ICGATE - condiţie iniţială pentru starea tiristorului:
ICGATE=0 - tiristorul este iniţial blocat, ICGATE=1 - tiristorul este iniţial în
conducţie. Acest ultim parametru este foarte util în anumite circuite, unde este
necesar ca tiristorul să fie iniţial în conducţie, iar momentul de aplicare al impulsului
de comandă nu coincide cu originea.

* Modelul simplificat al tiristorului. Include si sursa de comanda.

* A K
.SUBCKT SCR1 1 2 PARAMS: TDLY=1u WIDTH=100uT =20m
ICGATE=0
VG 3 2 PULSE(0 2{TDLY} 1u 1u {WIDTH}{T})
S1 1 5 6 2 SMOD
RG 3 4 50
VX 4 2 0
VY 5 7 0
DT 7 2 DMOD
RT 6 2 1
CT 6 2 10u IC={ICGATE}
F1 2 6 POLY(2) VX VY 0 50 11
.MODEL SMOD VSWITCH(RON=0.0125 ROFF=10e+5 VON=0.5 VOFF=0)
.MODEL DMOD D(IS=2.2e-15 BV=1800v TT=0)
.ENDS SCR1
Circuitul de test este prezentat în figura 3b. Pentru început va fi făcută o
simulare folosind modelul tiristorulul din biblioteca Pspice. Ulterior modelul va fi
înlocuit cu modelul simplificat.

În continuare este prezentat fişierul de circuit L1_2.CIR.

Desfăşurarea aplicaţiei 21
* Circuit pentru studiul blocării tiristorului pe sarcina R-L
.PARAM R1=200 L1=500u
.LIB C:\PSPICE\L1\[Link]
.LIB C:\PSPICE\LIB\[Link]
* Tensiunea de alimentare scade de la +200V la -200V polarizând invers
* tiristorul şi permiţând studiul comutaţiei în blocare
V1 1 0 PULSE(-200 200 0 10n 2u 150u 300u)
R1 1 2 {R1}
L1 2 3 {L1}
XTH1 3 3a 0 2N6399
VG 3a 0 PULSE(0 20 15n 1n 5u 40u 300u)
* Pentru folosirea modelului PSpice se validează cele două linii anterioare
* Pentru folosirea modelului simplificat se validează linia următoare
*XTH1 3 0 SCR1 PARAMS: TDLY=15n WIDTH=40u T=300u
ICGATE=0
.TRAN 10.000u 300.000u 0
.END

Fig. 3 a) modelul simplificat al tiristorului;

b) circuitul de test.

Rezultatele simulării folosind modelul PSpice pentru tiristor sunt prezentate în

figura 4.
22 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE

Fig. 4 Comutaţia tiristorului pe sarcină R-L.

Simularea SPICE
a) Se încarcă şi se studiază fişierul TH_PS.CIR. Acest fişier conţine modelul
PSpice al tiristorului. Comparaţi complexitatea modelului PSpice cu a modelului
simplificat.
b) Se încarcă fişierul de circuit L1_2.CIR. Se verifică faptul că este folosit
modelul tiristorului 2N6399.
c) Se efectuează analiza de regim tranzitoriu. Se vizualizează, pe grafice
distincte, tensiunea pe tiristor - v(3) şi curentul prin tiristor - i(L1). Folosind Zoom
se vizualizează procesul de comutare în blocare. Să se determine: valoarea
maximă a curentului invers - I RM , valoarea supratensiunii de polarizare inversă -
U RM , valoarea timpului de revenire inversă trr . Notaţi valoarea Total job time (ultima
linie a fişierului L1_2.OUT, care poate fi vizualizat cu Browse output).
d) Se modifică fişierul de circuit astfel încât să fie folosit modelul simplificat al
tiristorului. Se repetă punctul c).
e) Ce concluzii puteţi trage referitor la cele două modele din punct de vedere
al acurateţii şi al timpului necesar simulării? În ce situaţii credeţi că se poate folosi
modelul simplificat şi în ce situaţii trebuie folosit modelul Pspice?
3.3. Caracteristicile TEC-MOS de putere
Desfăşurarea aplicaţiei 23
3.3.1. Caracteristicile statice ale TEC-MOS de putere. Rezistenţa rDS (ON )
Schema circuitului de test este prezentată în figura 5. Este analizat
tranzistorul TEC-MOS de tip IRF150.

Fig. 5 Circuitul de test pentru determinarea caracteristicilor statice.

Fişierul de circuit corespunzător este prezentat în continuare.

* Studiul caracteristicilor statice ale tranzistorului MOS : id(vds). Rezistenta
rds(ON).
* Apelarea bibliotecii [Link], ce include modele pentru TEC-MOS de putere
.LIB C:\PSPICE\LIB\[Link]
VGS 1 0 1
VIG 1 2 0 ;pentru vizualizarea curentului prin terminalul G
M1 3 2 0 0 IRF150
VID 4 3 0 ;pentru vizualizarea curentului prin terminalul
D
VDS 4 0 1
* Analiza de tip DC Sweep
.DC LIN VDS 0 5 .1 LIN VGS 0 20 2
* Se dezactivează linia anterioară pentru determinarea caracteristicilor complete
id(vds) (inclusiv regiunea activă) şi se activează linia următoare.
*.DC LIN VDS 0 50 1 LIN VGS 0 20 2
.END
Caracteristicile statice i D ( v DS ) în zona ohmică sunt prezentate în figura 6.

Simularea SPICE
a) Se încarcă fişierul L1_3.CIR. Se verifică faptul că este setată analiza de tip
DC Sweep cu valorile lui v DS baleiate în intervalul (0, 5)V cu pas de 0,1V iar ale lui
vGS în intervalul (0, 20)V cu pas de 2V. Se efectuează simularea SPICE.
b) Se vizualizează caracteristicile iD(M1) funcţie de v(3), deci de v DS . Ţinând
cont de faptul că în regiunea ohmică tranzistorul se comportă ca o rezistenţă
comandată de tensiunea vGS , să se determine valorile rDS ( ON ) pentru fiecare valoare
a lui vGS .
24 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE

Fig. 6 Caracteristicile statice iD (vDS ) cu VGS parametru.

De ce pentru VGS =2V rezistenţa rDS are valoare foarte mare? Vizualizaţi
folosind Probe caracteristicile rDS (ON ) cu VGS parametru. Trasaţi graficul rDS (VGS )
pentru regiunea ohmică. Puteţi folosi Probe pentru a trasa acest grafic? Explicaţi
graficul obţinut cu Probe.
Cât este rezistenţa minimă rDS (ON ) ? Pentru ce valoare VGS se obţine? Ce
concluzie se poate trage cu privire la amplitudinea necesară pentru semnalul de
comandă?
c) Se modifică fişierul de circuit L1_3.CIR pentru a permite vizualizarea
caracteristicilor complete iD (vDS ) (v. indicaţie în fişierul de circuit). Se efectuează
analiza SPICE. Se vizualizează caracteristicile iD (vDS ) . Pentru fiecare valoare a lui
VGS se determină valoarea lui VDS lim ita la care are loc trecerea din regiunea ohmică în
regiunea activă. Folosind valorile pentru rDS (ON ) obţinute la punctul anterior se
trasează graficul rDS (ON ) funcţie de VDS lim ita .
d) Se încarcă fişierul de circuit L1_4.CIR. Acest fişier, similar celui prezentat
anterior, permite obţinerea caracteristicii de transfer iD (vGS ) . Se verifică faptul că
VDS =25V. Se efectuează analiza SPICE. Se vizualizează caracteristica iD (vGS ) .
Depinde această caracteristică de tensiunea VDS ? Se modifică fişierul de circuit
astfel încât să se poată obţine caracteristicile iD (vGS ) cu VDS parametru, unde VDS
variază între 1 şi 50V cu pas de 1V. Se determină tensiunea de prag VGST . Care
este regiunea ohmică şi care este regiunea activă? Se revine la forma iniţială a
fişierului L1_4.CIR.

3.3.2. Determinarea capacităţii de intrare Ciss

Schema de test este cea din figura 5. În continuare este prezentat fişierul de
circuit.
* Determinarea capacităţii de intrare Ciss=Cgd+Cgs
.LIB C:\PSPICE\LIB\[Link]
VGS 1 0 PULSE(0 20 0 20u 1u 1 2)
VIG 1 2 0
Desfăşurarea aplicaţiei 25
M1 3 2 0 0 IRF150
VID 4 3 0
VDS 4 0 0 ; sursaVDS a fost pasivizată
.DC LIN VGS 0 20 1
.TRAN 10.000n 20.000u 0 10.000n
.END
Pentru determinarea capacităţii de intrare sursa de tensiune VDS a fost
pasivizată ( VDS = 0 ). Capacitatea de intrare Ciss este formată din capacitatea C gs în
paralel cu capacitatea C gd : Ciss = C gd + C gs .
Se aplică la intrare tensiunea vGS liniar crescătoare în timp, cu panta de 1V/µ
s. Ţinând cont că iC = C duC dt şi că duC dt = 1V µs , dacă se vizualizează iC (vGS ) în
miliamperi, se vizualizează practic caracteristica Ciss (vGS ) în nanofarazi.
Se încarcă fişierul de circuit L1_5.CIR. Cum a fost obţinută tensiunea
crescătoare v GS cu panta de 1V/µs? Se efectuază analiza de regim tranzitoriu. Se
vizualizează forma de undă i(VIG) (curentul prin sursa de tensiune VIG ) în funcţie de
vGS . Se obţine astfel caracteristica Ciss [nF] în funcţie de vGS . Caracteristica este
valabilă doar pentru VGS < VGST (tensiunea VGS de prag). Se determină valoarea lui
Ciss [nF]. Se determină valorile pentru C gs şi C gd (indicaţie: caracteristica pentru C gd
este, în condiţiile precizate, caracteristica −iD ( M1)).

3.3.3. Determinarea capacităţii de ieşire Coss

Schema de test este cea din figura 5, în care se pasivizează sursa de intrare
VGS = 0.
În continuare este prezentat fişierul de circuit L1_6.CIR.

* Determinarea capacităţii de ieşire Coss=Cgd+Cds

.LIB C:\PSPICE\LIB\[Link]
VGS 1 0 0 ; sursa VGS a fost pasivizată
VIG 1 2 0
M1 3 2 0 0 IRF150
VID 4 3
VDS 4 0 PULSE(0 50 0 50u 1u 1 2)
.TRAN 10.000n 50.000u 0 0
.END
Capacitatea de ieşire Coss este formată din capacitatea Cds în paralel cu
capacitatea C gd : Coss = C ds + C gd .
Sursa de tensiune VDS generează o tensiune liniar crescătoare cu panta de
1V/µs, pentru a determina caracteristica Coss funcţie de v DS conform metodei
descrise la punctul anterior.
26 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE
Caracteristicile Coss şi C gd funcţie de tensiunea v DS sunt prezentate în figura
7.

Fig. 7 Coss şi Cgd funcţie de v DS .

Simularea SPICE
a) Se încarcă fişierul de circuit L1_6.CIR. Se efectuează analiza de regim
tranzitoriu. Se vizualizează caracteristica i(VID) funcţie de v(3), deci de vDS . Se
obţine astfel caracteristica Coss [nF] în funcţie de vDS .
b) Să se determine caracteristicile C ds şi C gd funcţie de vDS folosind o metodă
asemănătoare celei descrise la punctul 3.3.2. Care sunt valorile pentru cele trei
capacităţi la VDS = 20V ?

3.3.4. Studiul regimului de comutaţie al tranzistorului MOS de putere

Circuitul de test folosit este prezentat în figura 8.

Fig. 8 Circuitul de test pentru studiul regimului de comutaţie al tranzistorului MOS.

Circuitul modelează regimul de comutaţie pe sarcină puternic inductivă.

Atunci când tiristorul este comandat în conducţie de către sursa de comandă VG ,
tranzistorul M 1 preia conducţia curentului generat de sursa de curent constant I o .
Atunci când tranzistorul M 1 este comandat în blocare, conducţia curentului este
preluată de către dioda D1 .
Desfăşurarea aplicaţiei 27
Fişierul de circuit L1_7.CIR este prezentat în continuare.
* Circuit pentru studiul regimului de comutatie al tranzistorului MOS de putere
* Apelarea bibliotecii [Link]
.LIB C:\PSPICE\LIB\[Link]
* Definirea modelului diodei D1
.MODEL DNUL D(CJO=1e-10)
* Definirea palierelor tensiunii de comanda prin parametri
* pentru o mai usoara modificare a acestora
.PARAM VMAX=20 VMIN=-20
* Tensiunea de comanda
VGS 1 0 PULSE({VMIN} {VMAX} 10n 10n 10n 2.5u 50u)
RG 1 2 100
M1 3 2 0 0 IRF150
VID 4 3 0
D1 4 5 DNUL
IO 5 4 50A
VDS 5 0 100
.TRAN 1.000u 10.000u 0
.OPTIONS ITL5 = 0
.END

Simularea SPICE
a) Se încarcă fişierul L1_7.CIR. Se verifică faptul că VMAX = 20V , VMIN = −20V .
Se efectuează analiza de regim tranzitoriu.
În continuare se vor vizualiza formele de undă folosind Probe. Se adaugă
încă un grafic. Pe graficul de sus se vizualizează v(3) -tensiunea v DS şi iD(M1) -
curentul de drenă. Pe graficul de jos se vizualizează v(1) -tensiunea de comandă şi
v(2) -tensiunea v GS . În figura 9 sunt prezentate formele de undă respective. Tot în
figura 9 sunt prezentate şi definiţiile pentru timpii de comutaţie tON şi tOFF .
Explicaţi formele de undă prezentate în figura 9.
Se determină timpii de comutaţie în conducţie - tON şi în blocare - tOFF pentru
această situaţie.
Se vizualizează puterea instantanee disipată pe tranzistor - iD( M 1) ⋅ v(3) .
Estimaţi puterea disipată pe tranzistor ţinând cont că frecvenţa de comutaţie este de
20kHz şi că PD = f (WON + WOFF ) .
28 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE

Fig. 9 Procesul de comutaţie al tranzistorului MOS de putere.

b) Se repetă punctul a) pentru VMAX =20V, VMIN =0V (tensiune de comandă

unipolară). Cum se modifică timpii de comutaţie? Dar puterea disipată pe
tranzistor?
c) Se repetă punctul a) pentru VMAX =10V, VMIN = -10V (tensiune de comandă
bipolară de amplitudine mai mică). Cum se modifică timpii de comutaţie şi puterea
disipată pe tranzistor?
d) Se repetă punctul a) pentru VMAX =10V, VMIN =0V (tensiune de comandă
unipolară de amplitudine mai mică). Cum se modifică timpii de comutaţie şi puterea
disipată pe tranzistor?
e) Analizaţi rezultatele obţinute la punctele a)÷d) şi formulaţi concluzii referitor
la tipul şi parametrii tensiunii de comandă asupra timpilor de comutaţie şi puterii
disipate pe tranzistor.
f) Se repetă punctul a) pentru VMAX =20V, VMIN =-20V, RG =10Ω, respectiv
RG =1kΩ.
Cum se modifică timpii de comutaţie? Dar puterea disipată pe tranzistor?

3.4. Concepte de bază privind redresarea

În cadrul acestui punct se studiază redresarea monoalternanţă pe sarcină
rezistiv inductivă fără diodă de nul. Circuitul de test este prezentat în figura 10.
Desfăşurarea aplicaţiei 29

Fig. 10 Circuitul de test pentru studiul redresării monoalternanţă.

În continuare este prezentat fişierul de circuit corespunzător - L1_8.CIR.

* Circuitul de test pentru studiul redresării monoalternanţă pe sarcină RL
* Definirea unui model simplificat de diodă redresoare
.MODEL D_REDR D(RS=0.01 CJO=100p)
* Definirea diodei cu snubber RC
.SUBCKT D_SNUBBER a k
D1 a k D_REDR
RSNUB a aux 1k
CSNUB aux k 100n
.ENDS
.PARAM FRECV=50
VS 1 0 SIN(0 310 {FRECV} 0 0 0)
X1 1 2 D_SNUBBER
* Pentru analiza folosind dioda fără snubber se devalidează linia anterioară
* şi se validează linia următoare
*D1 1 2 D_REDR
LS 2 3 50mH
RS 3 0 5
.TRAN 10.000u .02 0 0
.OPTIONS ITL5 = 0
.END
Se remarcă definirea unei diode cu snubber RC folosind subcircuitul X1 .
Snubberul are doar rolul de a micşora neliniaritatea caracteristicii diodei D_REDR,
neliniaritate care duce la paşi mici de timp în momentele de comutaţie şi implicit la
mărirea timpului de simulare. Valorile alese pentru R şi C nu perturbă funcţionarea
circuitului în sine.
Formele de undă rezultate în urma simulării sunt prezentate în figura 11.

Simularea SPICE
a) Se încarcă fişierul L1_8.CIR. Se verifică faptul că simularea se va face
folosind dioda D_SNUBBER. Se efectuează analiza de regim tranzitoriu. Se
vizualizează formele de undă v(1) -tensiunea Vs , v(2,3) -tensiunea pe LS , v(3) -
30 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE
tensiunea pe RS , i(LS) curentul prin L S. Se determină valoarea unghiului de
conducţie γ al curentului prin diodă.

Fig. 11 Redresarea monoalternanţă pe sarcină RL.

b) De ce conducţia curentului prin diodă continuă şi după ce tensiunea de

intrare devine negativă? Cât trebuie să fie valoarea medie a tensiunii pe inductanţa
LS în regim permanent de funcţionare?
c) Se vizualizează forma de undă a tensiunii pe dioda D1 .
d) Cât a fost timpul necesar simulării în cazul a) ? (Din meniul Files se
selectează Browse Output, adică se vizualizează conţinutul fişierului L1_8.OUT. Pe
ultima linie a acestui fişier este indicat Total job time.)
e) În locul diodei D_SNUBBER se introduce dioda D_REDR. Se reface
simularea. Ce deosebiri constataţi faţă de situaţia anterioară, atât în ceea ce
priveşte formele de undă cât şi timpul total de simulare? Care este cauza
deosebirilor?
f) Se încarcă fişierul L1_9.CIR. Deosebirea faţă de situaţia de la punctul a)
este că rezistenţa de sarcină RS a fost înlocuită cu o sursă de tensiune continuă
V1=250V. Se efectuează analiza de regim tranzitoriu. Se vizualizează formele de
undă v(1) -tensiunea Vs , v(2,3) -tensiunea pe LS , v(3) -tensiunea generată de V1 ,
i(LS) curentul prin LS . Care este valoarea unghiului de conducţie γ al curentului prin
diodă în acest caz?
Desfăşurarea aplicaţiei 31
De ce conducţia are loc pe un interval mai mic? În ce moment curentul prin
inductanţa LS are valoarea maximă şi de ce? Care ar trebui să fie valoarea tensiunii
V1 pentru a nu fi posibilă conducţia curentului prin D1 ?
3.5. Concepte de bază privind comutaţia curentului în redresoare

3.5.1. Comutaţia la redresorul necomandat cu diode

Circuitul de test este prezentat în figura 12 şi permite studiul procesului de
comutaţie a curentului în redresoare. Sursa de curent constant modelează o sarcină
puternic inductivă. În circuit X 1 şi X 2 sunt diodele cu snubber, pe care le vom
denumi în continuare D1 şi D2 . Dioda de nul D2 asigură o cale de curent pentru
curentul de sarcină (constant) atunci când dioda D1 este blocată. Inductanţa LC
modelează inductanţa de scăpări a transformatorului de alimentare. Cazul
redresorului cu diodă de nul, sarcină puternic inductivă şi transformator de
alimentare cu inductanţă de scăpări este cel mai frecvent întâlnit.

Fig. 12 Circuitul de test pentru studiul comutaţiei în redresoare.

Fişierul de circuit folosit pentru analiza SPICE este prezentat în continuare.

* Circuit de test pentru studiul comutaţiei în redresoare
* Apelarea bibliotecii [Link]
C:\PSPICE\L1\[Link]
.PARAM FRECV=50HZ
VS 1 0 SIN(0 310 {FRECV} 0 0 0)
LC 1 2 5mH IC=0
X1 2 3 D_SNUBBER
X2 0 3a D_SNUBBER
* Pentru vizualizarea curentului prin X2
VIX2 3a 3
IO 3 0 10A
.TRAN 10.000u .02 0 0 UIC
.OPTIONS ITL5 = 0
.END
Sursa VIX 2 a fost inclusă pentru a permite vizualizarea curentului prin X 2 ,
adică practic prin dioda D2 . PSpice nu permite vizualizarea directă a curentului
printr-un anumit terminal al unui subcircuit.
În figura 13 sunt prezentate formele de undă pentru v(1), v(3), i(LC) şi i(VIX2).
32 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE
În cazul transformatorului ideal, fără inductanţă de scăpări, dioda D1 preia
practic instantaneu conducţia de la dioda de nul D2 atunci când tensiunea de
alimentare devine pozitivă. De asemenea, dioda de nul D2 preia instantaneu
conducţia de la dioda D1 atunci când tensiunea de alimentare devine negativă.

Fig. 13 Procesul de comutaţie într-un redresor cu sarcină puternic inductivă

şi transformator cu inductanţă de scăpări.

Aşa cum se poate observa din figura 13, în cazul real, al transformatorului cu
inductanţă de scăpări, procesul de comutaţie nu este instantaneu. Atunci când
tensiunea de alimentare VS devine pozitivă, dioda D1 nu poate prelua instantaneu
conducţia de la dioda D2 , prin care circulă curentul I 0 =10A. Acest fapt se datorează
inductanţei de scăpări LC , care se opune creşterii curentului prin ea. De asemenea,
atunci când tensiunea de alimentare devine negativă, dioda D2 nu poate prelua
instantaneu conducţia de la D1 , deoarece curentul prin LC nu se poate anula brusc.
Există deci, la ambele procese de comutaţie, un interval în care conducţia celor
două diode se suprapune, interval care se notează cu γ. Aşa cum se poate observa
din figura 13, pe durata primului interval de suprapunere a conducţiei tensiunea
redresată v(3) este practic nulă, deoarece dioda de nul D2 este încă deschisă.
Suprapunerea conducţiei celor două diode are deci ca efect direct micşorarea
valorii medii a tensiunii redresate şi deci reducerea eficienţei redresării. Fenomenul
Desfăşurarea aplicaţiei 33
este similar la redresoarele trifazate, unde se întâlneşte suprapunerea conducţiei a
două faze alăturate.

Simularea SPICE
a) Se încarcă fişierul L1_10.CIR. Se efectuează analiza de regim tranzitoriu.
De ce a fost necesar să fie specificată valoarea iniţială a curentului prin LC (IC=0)?
Se vizualizează formele de undă v(1), v(3), i(LC) şi i(VIX2). Sunt cele două intervale
de suprapunere a comutaţiei similare? Determinaţi valoarea unghiului γ (în grade).
b) Determinaţi expresia analitică a valorii unghiului γ. Se neglijează căderea
de tensiune pe diodele D1 şi D2 , ambele fiind în conducţie pe intervalul γ.
Pentru comutaţia de la D2 la D1 ecuaţiile sunt:
i1 + i2 = I 0 = ct.

Vs = U sin ωt = LC di1
 dt
i1 (0) = 0

i1 (γ ) = I 0
Comparaţi valoarea obţinută teoretic cu cea obţinută practic.
Scrieţi ecuaţiile corespunzătoare comutaţiei de la D1 la D2 . Se obţine aceeaşi
expresie analitică pentru γ?
c) Cum se modifică γ dacă inductanţa LC se micşorează de două ori iar I 0 se
dublează. Dar dacă amplitudinea U a tensiunii de alimentare se dublează?

3.5.2. Comutaţia la redresorul comandat cu tiristoare

Circuitul de test este prezentat în figura 14 şi permite studiul principalelor
aspecte întâlnite în convertoarele comandate cu tiristoare: posibilitatea reglajului
puterii prin modificarea unghiului de comandă α, transferul conducţiei de la o fază la
alta,

Fig. 14 Circuitul de test pentru studiul comutaţiei în convertorul

controlat cu tiristoare.
suprapunerea conducţiei a două faze alăturate datorită inductanţelor de scăpări ale
transformatorului de alimentare.
34 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE

Circuitul este un redresor bifazat, comandat la unghiul de comandă α = 45 .

Sursa de curent constant modelează o sarcină puternic inductivă. Inductanţele LC1
şi LC 2 modelează inductanţele de scăpări ale transformatorului de alimentare.

În continuare este prezentat fişierul de circuit folosit pentru analiza SPICE.

* Circuit de test pentru studiul comutaţiei în convertorul controlat cu tiristoare
.LIB C:\PSPICE\L1\[Link]
.PARAM FRECV=50
VS1 1 0 SIN(0 310 {FRECV} 0 0 0)
VS2 2 0 SIN(0 310 {FRECV} 0 0 -180)
LC1 1 3 10m
LC2 2 4 10m IC=10A
XTH1 3 5 SCR1 PARAMS:TDLY=5m ICGATE=0
XTH2 4 5 SCR1 PARAMS:TDLY=15m ICGATE=1
I0 5 0 10A
.TRAN 100.000u .04 0 0 UIC
.END
Se remarcă folosirea modelului simplificat de tiristor, care permite o simulare
foarte rapidă. De asemenea, la tiristorul X TH 2 , se remarcă folosirea condiţiei iniţiale
ICGATE=1, adică tiristor iniţial în conducţie. Dacă modelul tiristorului nu ar fi avut
această facilitate, nu am fi putut folosi condiţia iniţială IC=10A prin inductanţa LC 2 ,
pentru că până în momentul comenzii tiristorulul X TH 2 nu ar fi existat cale pentru
închiderea curentului prin LC 2 .
Formele de undă v(1) şi v(2) pentru tensiunile de intrare ( VS1 şi VS 2 ),
tensiunea redresată (V(5)), curenţii prin cele două faze i(LC1) şi i(LC2), sunt
prezentate în figura 15. Remarcăm două aspecte:
- tensiunea redresată poate lua valori instantanee negative, deoarece sursa
de curent constant (sarcina puternic inductivă) menţine curentul prin sarcină şi după
ce tensiunea fazei respective şi-a schimbat sensul.
- ca şi în exemplul analizat la punctul 3.5.1, datorită inductanţelor de scăpări
comutaţia curentului de la o fază la alta nu se poate face instantaneu. Există un
interval de suprapunere a conducţiei, notat cu γ . În acest caz particular, pe
intervalul γ tensiunea redresată este nulă, ceea ce înseamnă micşorarea valorii
medii a tensiunii redresate.

Simularea SPICE
a) Se încarcă fişierul L1_11.CIR. Se verifică faptul că unghiul de comandă
este α = 90 (TDLY=5m pentru X TH 1 , respectiv TDLY=15m pentru X TH 2 ) Se
efectuează analiza de regim tranzitoriu. Se vizualizează pe grafice distincte formele
de undă: ale tensiunii de alimentare v(1), v(2), ale tensiunii redresate v(5), ale
curentului prin cele două tiristoare i(LC1) şi i(LC2). Determinaţi valoarea unghiului
de suprapunere a conducţiei γ (în grade).
Desfăşurarea aplicaţiei 35
b) Determinaţi expresia analitică a valorii unghiului γ . Se neglijează căderea
de tensiune pe tiristoare.
Pentru comutaţia de la X TH 2 la X TH 1 ecuaţiile sunt:
i1 + i2 = I 0 = ct.

VS1 = U sin ωt = LC di1
 dt
i1 (α ) = 0

i1 (α + γ ) = I 0

Fig. 15 Forme de undă în convertorul comandat cu tiristoare.

Comparaţi valoarea teoretică a unghiului γ cu valoarea determinată analitic.

Determinaţi expresia analitică a valorii medii U D a tensiunii redresate în
absenţa inductanţelor de scăpări. Calculaţi valoarea medie U D pentru unghiul de
comandă α = 90 şi pentru datele din circuitul analizat.
Determinaţi expresia analitică a valorii medii U Dγ a valorii medii a tensiunii
redresate în prezenţa inductanţelor de scăpări. Calculaţi valoarea medie U Dγ pentru
unghiul de comandă α = 90 şi pentru datele din circuitul analizat.
c) Se modifică parametrii de comandă astfel încât unghiul de comandă să fie
α = 135 . Se vizualizează formele de undă indicate la punctul a). Cum este acum
valoarea medie a tensiunii redresate? Care este în acest caz sensul fluxului de
putere (de la sursă la sarcină sau invers)?
36 INTRODUCERE ÎN ANALIZA CIRCUITELOR DE COMUTAŢIE. MODELE SPICE

d) Concepeţi fişierul de circuit L1_12.CIR corespunzător unui redresor trifazat,

cu transformator cu inductanţă de scăpări şi sarcină puternic inductivă. (Indicaţie:
circuitul are trei ramuri sursă de tensiune - inductanţă L C - tiristor iar tensiunile
generate de cele trei surse trebuie să fie defazate cu câte 120º în loc de 180º ca în
circuitul analizat). Vizualizaţi forma de undă a tensiunii redresate. Calculaţi valoarea
medie a tensiunii redresate în acest caz (ţinând cont de inductanţa de scăpări).