@if not defined _echo @echo off

setlocal EnableDelayedExpansion EnableExtensions

set DOTNET_CLI_TELEMETRY_OPTOUT=1

set DOTNET_SKIP_FIRST_TIME_EXPERIENCE=1

set DOTNET_NOLOGO=1

set "__MsgPrefix=BUILD: "

set "__RepoRootDir=%~dp0"

REM Abstract submodule directory for case-sensitive filesystems

set "__DjvuLibreDir=djvulibre"

REM Delay resolving vcpkg root

set "__GlobalVcpkgRoot=(Resolving later...)"

REM Short circuit to help

if /i "%1"=="-help" goto usage

if /i "%1"=="-h" goto usage

if /i "%1"=="-?" goto usage

if defined VisualStudioVersion (

if not defined __VSVersion echo %__MsgPrefix%Detected Visual Studio %VisualStudioVersion% developer command ^prompt environment

goto :Run

)

echo %__MsgPrefix%Searching ^for Visual Studio 2026 installation

set _VSWHERE="%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe"

if exist %_VSWHERE% (

for /f "usebackq tokens=*" %%i in (`%_VSWHERE% -latest -prerelease -property installationPath`) do set _VSCOMNTOOLS=%%i\Common7\Tools

)

if not exist "%_VSCOMNTOOLS%" set _VSCOMNTOOLS=%VS80COMNTOOLS%

if not exist "%_VSCOMNTOOLS%" (

echo %__MsgPrefix%Error: Visual Studio 2026 required.++

echo Please see https://github.com/DjvuNet/DjvuNet for build instructions.

exit /b 1

)

set VSCMD_START_DIR="%~dp0"

call "%_VSCOMNTOOLS%\VsDevCmd.bat"

:Run

if not defined _VSCOMNTOOLS (

if defined VSINSTALLDIR (

set "_VSCOMNTOOLS=!VSINSTALLDIR!Common7\Tools"

) else (

set "_VSWHERE=!ProgramFiles(x86)!\Microsoft Visual Studio\Installer\vswhere.exe"

if exist "!_VSWHERE!" (

for /f "usebackq tokens=*" %%i in (`"!_VSWHERE!" -latest -prerelease -property installationPath`) do set "_VSCOMNTOOLS=%%i\Common7\Tools"

)

)

)

if defined _VSCOMNTOOLS (

set "__VSToolsRoot=%_VSCOMNTOOLS%"

set "__VCToolsRoot=%_VSCOMNTOOLS%\..\..\VC\Auxiliary\Build"

if defined VisualStudioVersion set __VSVersion=vs!VisualStudioVersion!

)

REM Set default values

set "_MSB_Target=Build"

set "_MSB_Configuration=Debug"

set "_MSB_Platform=x64"

set "_Verbosity=normal"

set "_Processors=0"

for /f "tokens=2 delims==" %%A in ('wmic cpu get NumberOfCores /value 2^>nul') do (

for /f "delims=" %%B in ("%%A") do set /a "_Processors+=%%B"

)

if !_Processors! EQU 0 set "_Processors=%NUMBER_OF_PROCESSORS%"

set "_TargetOS=Windows"

set "_SkipNative="

set "_CloneDeps="

set "_BuildDjvuNet=1"

set "_BuildTools="

set "_BuildTests="

set "_RunTests="

set "_Test="

set "_Pack="

set "_FastFail="

set "__FailedRestores="

set "__FailedBuilds="

set "__FailedPublishes="

set "__FailedTests="

set "__FailedClones="

set "__FailedCommands="

set "__SuccessfulRestores="

set "__SuccessfulBuilds="

set "__SuccessfulPublishes="

set "__SuccessfulTests="

set "__SuccessfulClones="

set "__SuccessfulCommands="

set "_DefaultNetCoreApp=net10.0"

set "_NetCoreAppId=.NETCoreApp"

set "_NetCoreAppTFM=.NETCoreApp,Version=v10.0"

set "_Framework=%_DefaultNetCoreApp%"

set "__ArtifactsReleaseTag=v0.16.26267.0"

set "__GithubDjvuNetReleaseUri=https://github.com/DjvuNet/artifacts/releases/download/%__ArtifactsReleaseTag%/"

set "__ArtifactsTestDataUri=https://github.com/DjvuNet/artifacts/archive/refs/tags/%__ArtifactsReleaseTag%.zip"

set "__ArtifactsDirName=artifacts-%__ArtifactsReleaseTag:v=%"

set "__LibGit2SharpRepoUri=https://github.com/4creators/libgit2sharp"

REM Parse command line

:parse

if /i "%1"=="" goto endparse

if /i "%~1"=="-Configuration" (set "_MSB_Configuration=%2"&shift&shift&goto :parse)

if /i "%~1"=="-c" (set "_MSB_Configuration=%2"&shift&shift&goto :parse)

if /i "%~1"=="-Platform" (set "_MSB_Platform=%2"&shift&shift&goto :parse)

if /i "%~1"=="-p" (set "_MSB_Platform=%2"&shift&shift&goto :parse)

if /i "%~1"=="-Target" (set "_MSB_Target=%2"&shift&shift&goto :parse)

if /i "%~1"=="-t" (set "_MSB_Target=%2"&shift&shift&goto :parse)

if /i "%~1"=="-BuildDjvuNet" (set "_BuildDjvuNet=1"&shift&goto :parse)

if /i "%~1"=="-DjvuNet" (set "_BuildDjvuNet=1"&shift&goto :parse)

if /i "%~1"=="-Tools" (set "_BuildTools=1"&shift&goto :parse)

if /i "%~1"=="-ts" (set "_BuildTools=1"&shift&goto :parse)

if /i "%~1"=="-BuildTests" (set "_BuildTests=1"&shift&goto :parse)

if /i "%~1"=="-bt" (set "_BuildTests=1"&shift&goto :parse)

if /i "%~1"=="-RunTests" (set "_RunTests=1"&shift&goto :parse)

if /i "%~1"=="-rt" (set "_RunTests=1"&shift&goto :parse)

if /i "%~1"=="-TestAll" (set "_TestAll=1"&shift&goto :parse)

if /i "%~1"=="-ta" (set "_TestAll=1"&shift&goto :parse)

if /i "%~1"=="-Test" (set "_Test=1"&shift&goto :parse)

if /i "%~1"=="-FastFail" (set "_FastFail=1"&shift&goto :parse)

if /i "%~1"=="-ff" (set "_FastFail=1"&shift&goto :parse)

if /i "%~1"=="-Framework" (set "_Framework=%2"&shift&shift&goto :parse)

if /i "%~1"=="-f" (set "_Framework=%2"&shift&shift&goto :parse)

if /i "%~1"=="-SkipNative" (set "_SkipNative=1"&shift&goto :parse)

if /i "%~1"=="-sn" (set "_SkipNative=1"&shift&goto :parse)

if /i "%~1"=="-CloneDeps" (

if /i "%~2"=="full" (set "_CloneDeps=full"&shift&shift&goto :parse) else (set "_CloneDeps=1"&shift&goto :parse)

)

if /i "%~1"=="-cdps" (

if /i "%~2"=="full" (set "_CloneDeps=full"&shift&shift&goto :parse) else (set "_CloneDeps=1"&shift&goto :parse)

)

if /i "%~1"=="-Verbosity" (set "_Verbosity=%2"&shift&shift&goto :parse)

if /i "%~1"=="-v" (set "_Verbosity=%2"&shift&shift&goto :parse)

if /i "%~1"=="-Processors" (set "_Processors=%2"&shift&shift&goto :parse)

if /i "%~1"=="-proc" (set "_Processors=%2"&shift&shift&goto :parse)

if /i "%~1"=="-OS" (set "_TargetOS=%2"&shift&shift&goto :parse)

echo Unknown command line parameter: %1

goto :usage

:endparse

if /i [!_MSB_Platform!] == [Arm] (set "__ManagedPlatform=!_MSB_Platform!" & if /i [!PROCESSOR_ARCHITECTURE!] == [AMD64] (set "__SkipNativeTests=1")&goto :check_params)

if /i [!_MSB_Platform!] == [Arm64] (set "__ManagedPlatform=!_MSB_Platform!" & if /i [!PROCESSOR_ARCHITECTURE!] == [AMD64] (set "__SkipNativeTests=1")&goto :check_params)

if /i [!_MSB_Platform!] == [AnyCPU] (set "_MSB_Platform=x64"&set "__ManagedPlatform=AnyCPU"&goto :check_params)

if /i [!_MSB_Platform!] == [x64] (set "_MSB_Platform=x64"&set "__ManagedPlatform=x64"&goto :check_params)

if /i [%__ManagedPlatform%] == [] set __ManagedPlatform=%_MSB_Platform%

if /i [%_MSB_Target%] == [Clean] set __SkipPublish=1

:check_params

REM Check params values

REM Accepted Framework values

if /i [%_Framework%] == [netcoreapp] (set "_Framework=%_DefaultNetCoreApp%"&set __TargetFrameworkMoniker=%_NetCoreAppTFM%&goto :end_check_framework)

if /i [%_Framework%] == [%_DefaultNetCoreApp%] (set __TargetFrameworkMoniker=%_NetCoreAppTFM%&goto :end_check_framework)

echo Invalid command line parameter -f/-Framework: %_Framework%

goto usage

:end_check_framework

REM Accepted Platform values

if /i [%_MSB_Platform%] == [x64] goto :end_check_platform

if /i [%_MSB_Platform%] == [x86] goto :end_check_platform

if /i [%_MSB_Platform%] == [arm] goto :end_check_platform

if /i [%_MSB_Platform%] == [arm64] goto :end_check_platform

echo Invalid command line parameter value -p/-Platform: %_MSB_Platform%

goto usage

:end_check_platform

REM Accepted Configuration values

if /i [%_MSB_Configuration%] == [Release] goto :end_check_configuration

if /i [%_MSB_Configuration%] == [Debug] goto :end_check_configuration

echo Invalid command line parameter value -c/-Configuration: %_MSB_Configuration%

goto usage

:end_check_configuration

REM Accepted Target values

if /i [%_MSB_Target%] == [Build] goto :end_check_target

if /i [%_MSB_Target%] == [Clean] goto :end_check_target

if /i [%_MSB_Target%] == [Rebuild] goto :end_check_target

if /i [%_MSB_Target%] == [Pack] goto :end_check_target

echo Invalid command line parameter value -t/-Target: %_MSB_Target%

goto usage

:end_check_target

REM Accepted Verbosity values

:: [ q[uiet], m[inimal], n[ormal], d[etailed], and diag[nostic] ]

if /i [%_Verbosity%] == [q] goto :end_check_verbosity

if /i [%_Verbosity%] == [quiet] (set _Verbosity=q&goto :end_check_verbosity)

if /i [%_Verbosity%] == [minimal] (set _Verbosity=m&goto :end_check_verbosity)

if /i [%_Verbosity%] == [m] goto :end_check_verbosity

if /i [%_Verbosity%] == [normal] (set _Verbosity=n&goto :end_check_verbosity)

if /i [%_Verbosity%] == [n] goto :end_check_verbosity

if /i [%_Verbosity%] == [detailed] (set _Verbosity=d&goto :end_check_verbosity)

if /i [%_Verbosity%] == [d] goto :end_check_verbosity

if /i [%_Verbosity%] == [diagnostic] (set _Verbosity=diag&goto :end_check_verbosity)

if /i [%_Verbosity%] == [diag] goto :end_check_verbosity

echo Invalid command line parameter value -v/-Verbosity: %_Verbosity%

goto usage

:end_check_verbosity

REM Accepted OS values

if /i [!_TargetOS!] == [Windows] goto :end_check_os

if /i [!_TargetOS!] == [Linux] goto :end_check_os

if /i [!_TargetOS!] == [OSX] goto :end_check_os

if /i [!_TargetOS!] == [macOS] (

set "_TargetOS=OSX"

goto :end_check_os

)

echo Invalid command line parameter value -OS: !_TargetOS!

goto usage

:end_check_os

:end_check_params

if defined _TestAll (

if defined _Test (

echo %__MsgPrefix%WARNING: Both -Test and -TestAll were provided.

echo %__MsgPrefix%WARNING: -TestAll takes precedence. Forcing unified test execution.

set "_Test="

)

if defined _SkipNative (

echo %__MsgPrefix%WARNING: Both -TestAll and -SkipNative were provided.

echo %__MsgPrefix%WARNING: -SkipNative has no effect with -TestAll for now.

)

set "_BuildDjvuNet=1"

set "_BuildTests=1"

set "_RunTests=1"

set "_SkipNative="

)

if defined _Test (

set "_BuildDjvuNet=1"

set "_BuildTests=1"

set "_RunTests=1"

)

if defined _BuildTests set _BuildDjvuNet=1

if defined _RunTests (

if not defined _BuildTests (

if not defined _Test (

set "_BuildDjvuNet="

)

)

)

set "__NeedsZstd="

if defined _Test set "__NeedsZstd=1"

if defined _BuildTests set "__NeedsZstd=1"

if defined _RunTests set "__NeedsZstd=1"

if defined __NeedsZstd (

where zstd.exe >nul 2>nul

if not [!ERRORLEVEL!]==[0] (

echo !__MsgPrefix!Error: zstd.exe not found on PATH. Required for test artifacts decompression.

set "__FailedCommands=!__FailedCommands! check_zstd"

set "_SkipTests=1"

if defined _FastFail goto exit_error

)

)

set "__RootBuildDir=%__RepoRootDir%build\bin\"

echo %__MsgPrefix%Starting Build of DjvuNet at %DATE% %TIME%

echo %__MsgPrefix%Repository Root: %__RepoRootDir%

echo %__MsgPrefix%Target OS: %_TargetOS%

echo %__MsgPrefix%Build Target: %_MSB_Target%

echo %__MsgPrefix%Configuration: %_MSB_Configuration%

echo %__MsgPrefix%Native Platform: %_MSB_Platform%

echo %__MsgPrefix%Managed Platform: %__ManagedPlatform%

echo %__MsgPrefix%Framework: %_Framework%

echo %__MsgPrefix%Vcpkg Root: %__GlobalVcpkgRoot%

echo %__MsgPrefix%VS Common Tools: %_VSCOMNTOOLS%

echo %__MsgPrefix%VS C++ Tools: %__VCToolsRoot%

if defined _BuildDjvuNet (

echo %__MsgPrefix%Build DjvuNet: True

) else (

echo %__MsgPrefix%Build DjvuNet: False

)

if defined _BuildTests (

echo %__MsgPrefix%Build Tests: True

) else (

echo %__MsgPrefix%Build Tests: False

)

if defined _RunTests (

echo %__MsgPrefix%Run Tests: True

) else (

echo %__MsgPrefix%Run Tests: False

)

set "TargetFramework=%_Framework%"

if not exist .\DjvuNet.sln (

echo %__MsgPrefix%Error: Missing DjvuNet.sln file in repository root directory %cd%

goto exit_error

)

REM Detect preferred PowerShell

set "__PSCmd=powershell"

where pwsh >nul 2>nul

if %ERRORLEVEL% equ 0 set "__PSCmd=pwsh"

REM Download ready to use DjvuNet build tools

set "__BuildToolsUri=!__GithubDjvuNetReleaseUri!Tools.zip"

if not exist ".\Tools\" (

echo %__MsgPrefix%Downloading DjvuNet.Build.Tools from !__BuildToolsUri!

call :download_retry "!__BuildToolsUri!" "Tools.zip"

if not [!ERRORLEVEL!]==[0] (

echo %__MsgPrefix%Error: Failed to download DjvuNet.Build.Tools from !__BuildToolsUri!

if defined _FastFail goto exit_error

) else (

mkdir Tools

tar.exe -xf Tools.zip -C Tools

del /f /q Tools.zip

)

) else (

echo %__MsgPrefix%DjvuNet.Build.Tools already restored

)

REM Download native build and test deps

set "__NativeDepsUri=!__GithubDjvuNetReleaseUri!deps.zip"

if not exist ".\deps\" (

echo %__MsgPrefix%Downloading custom System.Drawing.Common dependencies from !__NativeDepsUri!

call :download_retry "!__NativeDepsUri!" "deps.zip"

if not [!ERRORLEVEL!]==[0] (

echo %__MsgPrefix%Error: Failed to download custom System.Drawing.Common dependencies from !__NativeDepsUri!

if defined _FastFail goto exit_error

) else (

mkdir deps

tar.exe -xf deps.zip -C deps

del /f /q deps.zip

)

) else (

echo %__MsgPrefix%Custom System.Drawing.Common dependencies already restored

)

REM Download and initialize our own .NETCore SDK

set "__GlobalJson=%__RepoRootDir%global.json"

set "__TmpPsScript=%TEMP%\GetLatestSdk_%RANDOM%.ps1"

if not exist "%__RootBuildDir%" mkdir "%__RootBuildDir%"

(

echo $globalJsonPath = '%__GlobalJson%'

echo $globalJson = Get-Content $globalJsonPath ^| ConvertFrom-Json

echo $sdkVersion = $globalJson.sdk.version

echo $sdkChannel = $sdkVersion.Substring^(0, $sdkVersion.LastIndexOf^('.'^)^)

echo Write-Output "VERSION:$sdkVersion"

echo Write-Output "CHANNEL:$sdkChannel"

echo $latestPatchUrl = "https://dotnetcli.blob.core.windows.net/dotnet/Sdk/$sdkChannel/latest.version"

echo try {

echo $latestAvailable = ^(Invoke-RestMethod -Uri $latestPatchUrl^).Trim^(^)

echo Write-Output "LATEST:$latestAvailable"

echo } catch {

echo Write-Output "LATEST:$sdkVersion"

echo }

) > "%__TmpPsScript%"

for /f "usebackq tokens=1,2 delims=:" %%i in (`%__PSCmd% -NoProfile -ExecutionPolicy ByPass -File "%__TmpPsScript%"`) do (

if "%%i"=="VERSION" set "__SdkVersion=%%j"

if "%%i"=="CHANNEL" set "__SdkChannel=%%j"

if "%%i"=="LATEST" set "__LatestAvailable=%%j"

)

if exist "%__TmpPsScript%" del "%__TmpPsScript%"

echo %__MsgPrefix%Target .NET SDK Channel resolved to !__SdkChannel!

set "__UseSystemDotnetSdk=0"

set "__SystemDotnetVer="

for /f "usebackq tokens=*" %%v in (`dotnet --version 2^>nul`) do set "__SystemDotnetVer=%%v"

if defined __LatestAvailable (

if "!__SystemDotnetVer!"=="!__LatestAvailable!" set "__UseSystemDotnetSdk=1"

)

if "!__UseSystemDotnetSdk!"=="1" (

set "__DotNetCmd=dotnet.exe"

echo %__MsgPrefix%Globally installed System .NET SDK is up-to-date with latest secure patch: !__LatestAvailable!

) else (

echo %__MsgPrefix%======================================================================

if defined __SystemDotnetVer (

echo %__MsgPrefix%WARNING: System .NET SDK ^(!__SystemDotnetVer!^) is OUTDATED.

) else (

echo %__MsgPrefix%WARNING: System .NET SDK is MISSING.

)

echo %__MsgPrefix% The latest secure patch for channel !__SdkChannel! is !__LatestAvailable!.

echo %__MsgPrefix% Falling back to isolated local tools to ensure build security.

echo %__MsgPrefix%

echo %__MsgPrefix%STATUS: A secure, isolated .NET SDK [!__LatestAvailable!] is fully provisioned

echo %__MsgPrefix% within the repository context ^(Tools\coreclr\dotnetcli^).

echo %__MsgPrefix% All compilation and tool execution will map to this local instance

echo %__MsgPrefix% to maintain hermetic build guarantees and prevent CI state bleed.

echo %__MsgPrefix%======================================================================

REM ARCHITECTURAL NOTE: The official .NET SDK payloads for Windows are strictly compiled

REM targeting the MSVC Application Binary Interface (ABI) and Universal C Runtime (UCRT).

REM As discussed in early coreclr/runtime GitHub issues, it is structurally impossible to

REM build the core Windows .NET runtime with alternative compilers unless they perfectly

REM emulate MSVC (e.g., clang-cl.exe masquerading as cl.exe).

REM Because the payload binary contract is immutable, we statically isolate it under 'msvc'.

set "__OSName=win"

set "__Libc=msvc"

set "__ArchName=%PROCESSOR_ARCHITECTURE%"

if /i "!__ArchName!"=="AMD64" set "__ArchName=x64"

if /i "!__ArchName!"=="ARM64" set "__ArchName=arm64"

set "__LocalDotNetDir=!__RepoRootDir!Tools\coreclr\dotnetcli\!__OSName!\!__Libc!\!__ArchName!"

if defined __LatestAvailable (

if not "!__LatestAvailable!"=="!__SdkVersion!" (

echo %__MsgPrefix%Updating repository global.json to track target SDK version !__LatestAvailable! before initialization

%__PSCmd% -NoProfile -Command "$g = Get-Content '%__GlobalJson%' | ConvertFrom-Json; $g.sdk.version = '!__LatestAvailable!'; $g | ConvertTo-Json -Depth 10 | Set-Content '%__GlobalJson%'"

)

)

call "%__RepoRootDir%init-tools.cmd" %_MSB_Platform% "!__LocalDotNetDir!"

if not [!ERRORLEVEL!]==[0] (

goto exit_error

)

set "__DotNetCmd=!__LocalDotNetDir!\dotnet.exe"

set "DOTNET_ROOT=!__LocalDotNetDir!"

set "PATH=!__LocalDotNetDir!;!PATH!"

)

for /f "usebackq tokens=*" %%v in (`!__DotNetCmd! --version`) do set __UsedDotNetVersion=%%v

if "!__UseSystemDotnetSdk!"=="0" echo %__MsgPrefix%Using Isolated Repository-Local .NET SDK: !__UsedDotNetVersion!

REM Set target specific environment values

if /i "%_Framework%" == "%_DefaultNetCoreApp%" (

set DOTNET_SKIP_FIRST_TIME_EXPERIENCE=1

set DOTNET_MULTILEVEL_LOOKUP=0

set "__RestoreCmd=!__DotNetCmd! msbuild /t:Restore"

set "__BuildCommand=!__DotNetCmd! msbuild"

set "__Framework=%_DefaultNetCoreApp%"

set "__BuildLibDjvuLibre=0"

if /i [%_TargetOS%] == [Windows] set "__RuntimeIdentifier=win-"

if /i [%_TargetOS%] == [Linux] set "__RuntimeIdentifier=linux-"

if /i [%_TargetOS%] == [OSX] set "__RuntimeIdentifier=osx-"

set "__RuntimeIdentifier=!__RuntimeIdentifier!!_MSB_Platform!"

)

set "__SystemAttrProj=System.Attributes/System.Attributes.csproj"

set "__LibGit2SharpProj=eng/tools/libgit2sharp/LibGit2Sharp/LibGit2Sharp.csproj"

set "__DjvuNetGitTasksProj=eng/tools/DjvuNet.Build.Tasks/DjvuNet.Build.Tasks.csproj"

set "__DjvuNetProj=DjvuNet/DjvuNet.csproj"

set "__DjvuNetDjvuLibreProj=DjvuNet.DjvuLibre/DjvuNet.DjvuLibre.csproj"

if defined _BuildTools (

if not exist "!__RepoRootDir!!__LibGit2SharpProj!" (

echo !__MsgPrefix!Setting up libgit2sharp

set "__Lg2sArchiveUrl=!__LibGit2SharpRepoUri!/archive/refs/tags/!__ArtifactsReleaseTag!.tar.gz"

set "_ForceCloneLibGit2Sharp="

if defined _CloneDeps (

set "_ForceCloneLibGit2Sharp=1"

) else (

echo !__MsgPrefix!Downloading release archive of libgit2sharp for tag !__ArtifactsReleaseTag!

call :download_retry "!__Lg2sArchiveUrl!" "libgit2sharp.tar.gz"

if !ERRORLEVEL! EQU 0 (

echo !__MsgPrefix!Extracting libgit2sharp archive

if not exist "!__RepoRootDir!eng\tools\libgit2sharp" mkdir "!__RepoRootDir!eng\tools\libgit2sharp"

tar.exe -xzf libgit2sharp.tar.gz -C "!__RepoRootDir!eng\tools\libgit2sharp" --strip-components=1

del /f /q libgit2sharp.tar.gz

) else (

set "_ForceCloneLibGit2Sharp=1"

)

)

if defined _ForceCloneLibGit2Sharp (

echo !__MsgPrefix!Download bypassed or failed, falling back to git clone

set "__CloneArgs=-c core.autocrlf=false"

if not "!_CloneDeps!"=="full" set "__CloneArgs=--depth 1 !__CloneArgs!"

call :git_clone_retry ^

"!__LibGit2SharpRepoUri!.git" ^

"eng\tools\libgit2sharp" ^

"!__CloneArgs!"

)

)

)

set "__OutputDir=!__RootBuildDir!!_TargetOS!.!__ManagedPlatform!.!_MSB_Configuration!/binaries/!__Framework!/"

set "__PublishDir=!__OutputDir!!__RuntimeIdentifier!/publish/"

set "__LogsDir=!__RootBuildDir!!_TargetOS!.!__ManagedPlatform!.!_MSB_Configuration!/logs/!__Framework!/"

if not exist "!__LogsDir!" md "!__LogsDir!"

echo %__MsgPrefix%__OutputDir [!__OutputDir!]

echo %__MsgPrefix%__PublishDir [!__PublishDir!]

echo %__MsgPrefix%__LogsDir [!__LogsDir!]

call :get_time __BuildStartTime

if defined _BuildTools (

REM 1. Standard net10.0 Tools Restore

set "__BuildCommandArgs=-property:Configuration=!_MSB_Configuration! -property:Platform=!__ManagedPlatform! -property:TargetFramework=!__Framework! -p:RuntimeIdentifier=!__RuntimeIdentifier! -v:!_Verbosity! -m:!_Processors! -nologo -nr:false"

REM Omit TargetFramework during restore to allow multi-targeted projects to generate unified project.assets.json

set "__RestoreCmdArgs=-property:Configuration=!_MSB_Configuration! -property:Platform=!__ManagedPlatform! -p:RuntimeIdentifier=!__RuntimeIdentifier! -v:!_Verbosity! -m:!_Processors! -nologo -nr:false"

call :restore_dotnet_proj !__SystemAttrProj! System.Attributes.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

call :restore_dotnet_proj !__LibGit2SharpProj! LibGit2Sharp_!!__Framework!.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

call :restore_dotnet_proj !__DjvuNetGitTasksProj! DjvuNet.Build.Tasks_!!__Framework!.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

REM 2. Standard net10.0 Tools Build

call :build_dotnet_proj !__SystemAttrProj! System.Attributes.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

call :build_dotnet_proj !__LibGit2SharpProj! LibGit2Sharp_!!__Framework!.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

call :build_dotnet_proj !__DjvuNetGitTasksProj! DjvuNet.Build.Tasks_!!__Framework!.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

REM 3. Visual Studio net472 Tools Build (Only on Windows)

if /i "!_TargetOS!" == "Windows" (

echo %__MsgPrefix%======================================================================

echo %__MsgPrefix% Building Tools for Visual Studio in-process execution ^(net472^)

echo %__MsgPrefix%======================================================================

REM Backup original environment

set "__OrigFramework=!__Framework!"

set "__OrigManagedPlatform=!__ManagedPlatform!"

set "__OrigBuildCommandArgs=!__BuildCommandArgs!"

set "__OrigRestoreCmdArgs=!__RestoreCmdArgs!"

set "__OrigOutputDir=!__OutputDir!"

set "__OrigPublishDir=!__PublishDir!"

set "__OrigLogsDir=!__LogsDir!"

REM Set net472 environment

set "__Framework=net472"

set "__ManagedPlatform=AnyCPU"

set "__BuildCommandArgs=-property:Configuration=!_MSB_Configuration! -property:Platform=!__ManagedPlatform! -property:TargetFramework=!__Framework! -v:!_Verbosity! -m:!_Processors! -nologo -nr:false"

set "__RestoreCmdArgs=!__BuildCommandArgs!"

REM Recalculate paths exactly matching the tools output architecture

set "__OutputDir=!__RootBuildDir!!_TargetOS!.!__ManagedPlatform!.!_MSB_Configuration!/tools/binaries/!__Framework!/"

set "__PublishDir=!__RepoRootDir!Tools/DjvuNet/!__Framework!/"

set "__LogsDir=!__RootBuildDir!!_TargetOS!.!__ManagedPlatform!.!_MSB_Configuration!/logs/!__Framework!/"

if not exist "!__LogsDir!" md "!__LogsDir!"

echo %__MsgPrefix%Switched Framework to: !__Framework!

echo %__MsgPrefix%Updated OutputDir: !__OutputDir!

echo %__MsgPrefix%Updated PublishDir: !__PublishDir!

echo %__MsgPrefix%Updated LogsDir: !__LogsDir!

REM Restore phase skipped for net472. Multi-targeted project.assets.json was generated during the net10.0 restore phase.

call :build_dotnet_proj !__SystemAttrProj! System.Attributes.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

call :build_dotnet_proj !__LibGit2SharpProj! LibGit2Sharp_!!__Framework!.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

call :build_dotnet_proj !__DjvuNetGitTasksProj! DjvuNet.Build.Tasks_!!__Framework!.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

echo %__MsgPrefix%Restoring original environment properties...

set "__Framework=!__OrigFramework!"

set "__ManagedPlatform=!__OrigManagedPlatform!"

set "__BuildCommandArgs=!__OrigBuildCommandArgs!"

set "__RestoreCmdArgs=!__OrigRestoreCmdArgs!"

set "__OutputDir=!__OrigOutputDir!"

set "__PublishDir=!__OrigPublishDir!"

set "__LogsDir=!__OrigLogsDir!"

)

REM 4. Package Tools

if defined __SuccessfulBuilds (

if defined __SuccessfulPublishes (

if not "!__SuccessfulBuilds:DjvuNet.Build.Tasks_%_DefaultNetCoreApp%.csproj=!"=="!__SuccessfulBuilds!" (

if not "!__SuccessfulPublishes:DjvuNet.Build.Tasks_%_DefaultNetCoreApp%.csproj=!"=="!__SuccessfulPublishes!" (

set "__TmpPackageScript=!TEMP!\Package_!RANDOM!.ps1"

(

echo $ErrorActionPreference = 'Stop'

echo ^& '!__RepoRootDir!eng\scripts\PackageTools.ps1' -RepoRoot '!__RepoRootDir!' -Configuration '!_MSB_Configuration!'

echo exit $LASTEXITCODE

) > "!__TmpPackageScript!"

call :run_custom_command "!__PSCmd! -NoProfile -ExecutionPolicy Bypass -File !__TmpPackageScript!" "PackageTools.ps1"

if exist "!__TmpPackageScript!" del "!__TmpPackageScript!"

)

)

)

)

)

if defined _SkipNative goto :no_djvulibre

REM Clone libdjvulibre if needed

REM ---------------------------------------------------------------------------

REM 1. Clone libdjvulibre FIRST so we can read its vcpkg.json

REM ---------------------------------------------------------------------------

if not exist ".\%__DjvuLibreDir%\win32\djvulibre\libdjvulibre\libdjvulibre.vcxproj" (

echo %__MsgPrefix%Setting up DjVuLibre

set "__ArchiveUrl=https://github.com/DjvuNet/DjVuLibre/archive/refs/tags/!__ArtifactsReleaseTag!.tar.gz"

set "_ForceCloneDjvuLibre="

if defined _CloneDeps (

set "_ForceCloneDjvuLibre=1"

) else (

echo %__MsgPrefix%Downloading release archive of DjVuLibre for tag !__ArtifactsReleaseTag!

call :download_retry "!__ArchiveUrl!" "djvulibre.tar.gz"

if !ERRORLEVEL! EQU 0 (

echo %__MsgPrefix%Extracting DjVuLibre archive

if not exist "%__DjvuLibreDir%" mkdir "%__DjvuLibreDir%"

tar -xzf djvulibre.tar.gz -C "%__DjvuLibreDir%" --strip-components=1

del /f /q djvulibre.tar.gz

) else (

set "_ForceCloneDjvuLibre=1"

)

)

if defined _ForceCloneDjvuLibre (

echo %__MsgPrefix%Bypassing archive download, executing git clone

set "__CloneArgs=-c core.autocrlf=false"

if not "!_CloneDeps!"=="full" set "__CloneArgs=--depth 1 !__CloneArgs!"

call :git_clone_retry ^

"https://github.com/DjvuNet/DjVuLibre.git" ^

"%__DjvuLibreDir%" ^

"!__CloneArgs!"

)

if not [!ERRORLEVEL!]==[0] goto :skip_native_setup

) else (

echo %__MsgPrefix%DjVuLibre already cloned

)

REM ---------------------------------------------------------------------------

REM 2. Extract builtin-baseline from vcpkg.json cleanly

REM ---------------------------------------------------------------------------

set "__VcpkgBaseline="

set "__VcpkgJsonPath=%__RepoRootDir%%__DjvuLibreDir%\vcpkg.json"

if exist "%__VcpkgJsonPath%" (

set "__PsCommand=(Get-Content '%__VcpkgJsonPath%' | ConvertFrom-Json).'builtin-baseline'"

for /f "usebackq tokens=*" %%i in (`powershell -NoProfile -Command "!__PsCommand!" 2^>nul`) do (

set "__VcpkgBaseline=%%i"

)

)

REM ---------------------------------------------------------------------------

REM 3. Define the VCPKG validation subroutine

REM ---------------------------------------------------------------------------

goto :skip_vcpkg_validation

:is_valid_vcpkg

set "__TestDir=%~1"

if not exist "%__TestDir%\vcpkg.exe" exit /b 1

if not exist "%__TestDir%\.git\" exit /b 1

if defined __VcpkgBaseline (

git -C "%__TestDir%" cat-file -e "%__VcpkgBaseline%^{commit}" >nul 2>&1

if not !ERRORLEVEL!==0 exit /b 1

)

exit /b 0

:skip_vcpkg_validation

REM ---------------------------------------------------------------------------

REM 4. Resolve GlobalVcpkgRoot safely against the baseline

REM ---------------------------------------------------------------------------

set "__GlobalVcpkgRoot="

REM Check explicit environment variable first

if defined VCPKG_ROOT (

call :is_valid_vcpkg "%VCPKG_ROOT%"

if !ERRORLEVEL!==0 (

set "__GlobalVcpkgRoot=%VCPKG_ROOT%"

goto :vcpkg_found

)

)

REM Fallback to checking the system PATH

for /f "delims=" %%i in ('where vcpkg 2^>nul') do (

call :is_valid_vcpkg "%%~dpi."

if !ERRORLEVEL!==0 (

set "__GlobalVcpkgRoot=%%~dpi"

goto :vcpkg_found

)

)

REM Fallback to the local repository clone

set "__GlobalVcpkgRoot=%__RepoRootDir%vcpkg"

:vcpkg_found

if "%__GlobalVcpkgRoot:~-1%"=="\" (

set "__GlobalVcpkgRoot=%__GlobalVcpkgRoot:~0,-1%"

)

echo %__MsgPrefix%Resolved Vcpkg Root: !__GlobalVcpkgRoot!

REM ---------------------------------------------------------------------------

REM 5. Setup vcpkg baseline if local fallback was used

REM ---------------------------------------------------------------------------

if /i "%__GlobalVcpkgRoot%"=="%__RepoRootDir%vcpkg" (

set "__CloneValid=0"

if exist "%__GlobalVcpkgRoot%\.git\" (

if exist "%__GlobalVcpkgRoot%\bootstrap-vcpkg.bat" (

if exist "%__GlobalVcpkgRoot%\vcpkg.exe" (

if defined __VcpkgBaseline (

git -C "%__GlobalVcpkgRoot%" cat-file -e "%__VcpkgBaseline%^{commit}" >nul 2>&1

if !ERRORLEVEL!==0 set "__CloneValid=1"

) else (

set "__CloneValid=1"

)

)

)

)

if "!__CloneValid!"=="0" (

if exist "%__GlobalVcpkgRoot%\" (

echo %__MsgPrefix%Removing broken vcpkg baseline at %__GlobalVcpkgRoot%

rmdir /s /q "%__GlobalVcpkgRoot%"

)

echo %__MsgPrefix%Cloning local Microsoft vcpkg baseline

call :git_clone_retry ^

"https://github.com/Microsoft/vcpkg.git" ^

"vcpkg" ^

"-c core.autocrlf=false"

if not [!ERRORLEVEL!]==[0] goto :skip_native_setup

)

if not exist "%__GlobalVcpkgRoot%\vcpkg.exe" (

echo %__MsgPrefix%Bootstrapping vcpkg

call :run_custom_command ^

"%__GlobalVcpkgRoot%\bootstrap-vcpkg.bat -disableMetrics" ^

"vcpkg_bootstrap"

if not [!ERRORLEVEL!]==[0] goto :skip_native_setup

)

)

goto :no_djvulibre

:skip_native_setup

set "_SkipNative=1"

:no_djvulibre

if /i "%_MSB_Target%" == "Clean" goto :end_dotnet_restore

if not defined _BuildDjvuNet goto :skip_djvulibre_build

if /i "%_Framework%" == "%_DefaultNetCoreApp%" goto :dotnet_restore

goto :end_dotnet_restore

:dotnet_restore

REM Reset args for standard repository restore

set "__BuildCommandArgs=-property:Configuration=!_MSB_Configuration! -property:Platform=!__ManagedPlatform! -property:TargetFramework=!__Framework! -p:RuntimeIdentifier=!__RuntimeIdentifier! -v:!_Verbosity! -m:!_Processors! -nologo -nr:false"

set "__RestoreCmdArgs=!__BuildCommandArgs!"

if not defined _BuildTools (

call :restore_dotnet_proj !__SystemAttrProj! System.Attributes.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

)

call :restore_dotnet_proj !__DjvuNetProj! DjvuNet.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

:end_dotnet_restore

if defined _SkipNative goto :no_djvulibre_build

if defined __BuildLibDjvuLibre (

REM Scope environment changes start {

setlocal

echo %__MsgPrefix%Building native libdjvulibre.vcxproj

set "__HostArch=%PROCESSOR_ARCHITECTURE%"

if /i "!__HostArch!" == "AMD64" set "__HostArch=x64"

if /i "!__HostArch!" == "%_MSB_Platform%" (

set "__VCBuildArch=!__HostArch!"

) else (

set "__VCBuildArch=!__HostArch!_%_MSB_Platform%"

)

echo %__MsgPrefix%Using environment: "%__VCToolsRoot%\vcvarsall.bat" !__VCBuildArch!

call "%__VCToolsRoot%\vcvarsall.bat" !__VCBuildArch!

set "__NativeLogsDir=!__RootBuildDir!!_TargetOS!.!_MSB_Platform!.!_MSB_Configuration!/logs/native/msvc-!VCToolsVersion!/"

if not exist "!__NativeLogsDir!" md "!__NativeLogsDir!"

set "__BuildLogRootName=libdjvulibre"

set "__BuildLog=!__NativeLogsDir!!__BuildLogRootName!.log"

set "__BuildWrn=!__NativeLogsDir!!__BuildLogRootName!.wrn"

set "__BuildErr=!__NativeLogsDir!!__BuildLogRootName!.err"

set "__MsbuildLog="-flp:Verbosity=diag;LogFile=!__BuildLog!""

set "__MsbuildWrn="/flp1:WarningsOnly;LogFile=!__BuildWrn!""

set "__MsbuildErr="/flp2:ErrorsOnly;LogFile=!__BuildErr!""

set "__MsbuildLogging=!__MsbuildLog! !__MsbuildWrn! !__MsbuildErr!"

set "__VcpkgRootArg="

if defined __GlobalVcpkgRoot set "__VcpkgRootArg=/p:VcpkgRoot=!__GlobalVcpkgRoot!"

set "__VcpkgManifestArg=/p:VcpkgManifestDir=%__RepoRootDir%%__DjvuLibreDir%"

set "__PlatformToolsetArg="

if defined VisualStudioVersion (

if "!VisualStudioVersion:~0,3!"=="17." (

echo %__MsgPrefix%WARNING: Falling back to Visual Studio 2022 ^(v143^) toolset. This is an unsupported build configuration.

set "__PlatformToolsetArg=/p:PlatformToolset=v143"

)

if "!VisualStudioVersion:~0,3!"=="18." set "__PlatformToolsetArg=/p:PlatformToolset=v145"

)

echo %__MsgPrefix%Calling: msbuild /p:Configuration=%_MSB_Configuration% /p:Platform=%_MSB_Platform% /p:TargetFramework=%__Framework% /p:VcpkgEnableManifest=true !__VcpkgManifestArg! !__VcpkgRootArg! !__PlatformToolsetArg! /t:%_MSB_Target% /v:%_Verbosity% /m:%_Processors% /nologo /nr:false !__MsbuildLogging! "%__RepoRootDir%%__DjvuLibreDir%\win32\djvulibre\libdjvulibre\libdjvulibre.vcxproj"

call msbuild /p:Configuration=%_MSB_Configuration% /p:Platform=%_MSB_Platform% /p:TargetFramework=%__Framework% /p:VcpkgEnableManifest=true !__VcpkgManifestArg! !__VcpkgRootArg! !__PlatformToolsetArg! /t:%_MSB_Target% /v:%_Verbosity% /m:%_Processors% /nologo /nr:false !__MsbuildLogging! "%__RepoRootDir%%__DjvuLibreDir%\win32\djvulibre\libdjvulibre\libdjvulibre.vcxproj"

if not [!ERRORLEVEL!]==[0] (

echo %__MsgPrefix%Error: native libdjvulibre library build failed. Refer to the build log files for details:

echo !__BuildLog!

echo !__BuildWrn!

echo !__BuildErr!

set "_NativeFailed=1"

) else (

set "_NativeFailed=0"

)

REM } Scope environment changes end

for %%F in ("!_NativeFailed!") do (

endlocal

set "_NativeFailed=%%~F"

)

if "!_NativeFailed!"=="1" (

set "__FailedBuilds=!__FailedBuilds! libdjvulibre"

set "_SkipNative=1"

if defined _FastFail goto exit_error

) else (

set "__SuccessfulBuilds=!__SuccessfulBuilds! libdjvulibre"

)

)

:no_djvulibre_build

set "__LogsDir=!__RootBuildDir!!_TargetOS!.!_MSB_Platform!.!_MSB_Configuration!/logs/!__Framework!/"

if not exist "!__LogsDir!" md "!__LogsDir!"

if not defined _BuildTools (

call :build_dotnet_proj !__SystemAttrProj! System.Attributes.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

)

call :build_dotnet_proj !__DjvuNetProj! DjvuNet.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

if defined _SkipNative (

if "!_NativeFailed!"=="1" (

set "__FailedRestores=!__FailedRestores! DjvuNet.DjvuLibre.csproj"

set "__FailedBuilds=!__FailedBuilds! DjvuNet.DjvuLibre.csproj"

)

goto skip_djvulibre_build

)

echo %__MsgPrefix%Restoring DjvuNet.DjvuLibre project:

call :restore_dotnet_proj !__DjvuNetDjvuLibreProj! DjvuNet.DjvuLibre.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

echo.

echo %__MsgPrefix%Building DjvuNet.DjvuLibre project:

call :build_dotnet_proj !__DjvuNetDjvuLibreProj! DjvuNet.DjvuLibre.csproj

if defined _FastFail if not !ERRORLEVEL! EQU 0 goto exit_error

:skip_djvulibre_build

if not defined _Test (

if not defined _BuildTests (

if defined _RunTests (

echo %__MsgPrefix%Preparing to run tests on %_DefaultNetCoreApp%

) else (

if not "!__FailedCommands!" == "" goto exit_error

if not "!__FailedRestores!" == "" goto exit_error

if not "!__FailedBuilds!" == "" goto exit_error

if not "!__FailedPublishes!" == "" goto exit_error

goto exit_success

)

) else (

echo.

echo %__MsgPrefix%Preparing to build tests

)

) else (

echo.

echo %__MsgPrefix%Preparing to build and run tests

)

if not exist .\artifacts\test001C.djvu (

echo.

set "_ForceCloneArtifacts="

if defined _CloneDeps (

set "_ForceCloneArtifacts=1"

) else (

echo !__MsgPrefix!Downloading release archive of artifacts for tag !__ArtifactsReleaseTag!

call :download_retry "!__ArtifactsTestDataUri!" "artifacts.tar.gz"

if !ERRORLEVEL! EQU 0 (

if exist artifacts\ rmdir /s /q artifacts

mkdir artifacts

tar.exe -xzf artifacts.tar.gz -C artifacts --strip-components=1

if not [!ERRORLEVEL!]==[0] (

echo.

echo !__MsgPrefix!Error: artifacts extraction returned error

set "__FailedCommands=!__FailedCommands! extract_artifacts"

set "_ForceCloneArtifacts=1"

if defined _FastFail goto exit_error

) else (

del artifacts.tar.gz

)

) else (

set "_ForceCloneArtifacts=1"

)

)

if defined _ForceCloneArtifacts (

echo !__MsgPrefix!Download bypassed or failed, executing git clone for artifacts

if exist artifacts\ rmdir /s /q artifacts

set "__CloneArgs=-c core.autocrlf=false"

if not "!_CloneDeps!"=="full" set "__CloneArgs=--depth 1 !__CloneArgs!"

call :git_clone_retry ^

"https://github.com/DjvuNet/artifacts.git" ^

"artifacts" ^

"!__CloneArgs!"

if not [!ERRORLEVEL!]==[0] (

set "_SkipTests=1"

)

)

echo.

)

if not defined _SkipTests (

if exist artifacts\data\extracted\ (

echo.

echo !__MsgPrefix!Running: Decompress_Rle_Artifacts

pushd artifacts\data\extracted

if exist zstd_files.txt del zstd_files.txt

for %%f in (*.zst) do (

if not exist "%%~nf" echo %%f>> zstd_files.txt

)

if exist zstd_files.txt zstd.exe -d -f --no-progress --filelist zstd_files.txt

if not [!ERRORLEVEL!]==[0] (

echo !__MsgPrefix!Error: Decompress_Rle_Artifacts returned error code !ERRORLEVEL!

set "__FailedCommands=!__FailedCommands! Decompress_Rle_Artifacts"

set "_SkipTests=1"

if defined _FastFail (

popd

goto exit_error

)

) else (

set "__SuccessfulCommands=!__SuccessfulCommands! Decompress_Rle_Artifacts"

)

popd

)

)

echo.

if defined _SkipTests (

echo !__MsgPrefix!WARNING: Artifacts acquisition or decompression failed. Tests will be skipped.

set "_Test="

set "_BuildTests="

set "_RunTests="

)

REM Setup test environment